# -*- mode: python -*-
# OpenPGM build script
# $Id$

import os;

Import('env')
e = env.Clone()
e.Prepend(LIBS = ['libpgmex', 'libpgm']);
if e['WITH_SNMP'] == 'true':
	e.Append(CCFLAGS = ['-DCONFIG_WITH_SNMP']);
	e.Prepend(LIBS = ['libpgmsnmp']);
	e.MergeFlags(e['SNMP_FLAGS']);
if e['WITH_HTTP'] == 'true':
	e.Append(CCFLAGS = ['-DCONFIG_WITH_HTTP']);
	e.Prepend(LIBS = ['libpgmhttp']);
	e.MergeFlags(e['LIBSOUP_FLAGS']);

# core preferred examples
e.Program(['pgmdump.c'])
e.Program(['pgmsend.c'])
e.Program(['pgmrecv.c'])

# sync examples
e.Program(['blocksyncrecv.c'])
e.Program(['snonblocksyncrecv.c'])
if '-DCONFIG_HAVE_POLL' in e['CCFLAGS']:
	e.Program(['pnonblocksyncrecv.c'])

# epoll based examples
if '-DCONFIG_HAVE_EPOLL' in e['CCFLAGS']:
	e.Program(['enonblocksyncrecv.c'])
	e.Program(['enonblocksyncrecvmsg.c'])
	e.Program(['enonblocksyncrecvmsgv.c'])

# async examples
e.Program(['asyncqrecv.c'])
e.Program(['blockqrecv.c'])

# ncurses examples
if e['WITH_NCURSES'] == 'true':
	ne = e.Clone()
	ne.Append(LIBS = ['panel', 'ncurses']);
	ne.Program(['pgmtop.c'])

# Google Protocol Buffer example
if e['WITH_PROTOBUF'] == 'true':
	ge = e.Clone();
	newCCFLAGS = [];
	for flag in ge['CCFLAGS']:
		if ("-W" != flag[:2]) and ("-std=gnu99" != flag[:10]) and ("-pedantic" != flag[:9]) and ("-D_XOPEN_SOURCE=600" != flag[:19]) and ("-xc99=all" != flag[:9]):
			newCCFLAGS.append(flag);
		if ("-D_XOPEN_SOURCE=600" == flag[:19]):
			newCCFLAGS.append("-D_XOPEN_SOURCE=500");
	ge['CCFLAGS'] = newCCFLAGS;
	ge.Append(CPPPATH = '.');
	ge.Append(CCFLAGS = ge['PROTOBUF_CCFLAGS']);
	ge.Depends('pgmping.cc', ['ping.pb.cc', 'ping.pb.h']);
	protobuf = Builder(action = 'cd ${SOURCE.dir} && %s ${SOURCE.file} --cpp_out=../${TARGET.dir}' % ge['PROTOBUF_PROTOC'])
	ge.Append(BUILDERS = {'Protobuf' : protobuf})
	ge.Protobuf('ping.pb.cc', 'ping.proto')
	ge.Program(['pgmping.cc', 'ping.pb.cc', ge['PROTOBUF_LIBS']])

# end of file
