#!/bin/sh

#{{{ copyright

#   featregapply - apply registration in a FEAT directory
#
#   Stephen Smith, FMRIB Image Analysis Group
#
#   Copyright (C) 2002-2007 University of Oxford
#
#   Part of FSL - FMRIB's Software Library
#   http://www.fmrib.ox.ac.uk/fsl
#   fsl@fmrib.ox.ac.uk
#   
#   Developed at FMRIB (Oxford Centre for Functional Magnetic Resonance
#   Imaging of the Brain), Department of Clinical Neurology, Oxford
#   University, Oxford, UK
#   
#   
#   LICENCE
#   
#   FMRIB Software Library, Release 4.0 (c) 2007, The University of
#   Oxford (the "Software")
#   
#   The Software remains the property of the University of Oxford ("the
#   University").
#   
#   The Software is distributed "AS IS" under this Licence solely for
#   non-commercial use in the hope that it will be useful, but in order
#   that the University as a charitable foundation protects its assets for
#   the benefit of its educational and research purposes, the University
#   makes clear that no condition is made or to be implied, nor is any
#   warranty given or to be implied, as to the accuracy of the Software,
#   or that it will be suitable for any particular purpose or for use
#   under any specific conditions. Furthermore, the University disclaims
#   all responsibility for the use which is made of the Software. It
#   further disclaims any liability for the outcomes arising from using
#   the Software.
#   
#   The Licensee agrees to indemnify the University and hold the
#   University harmless from and against any and all claims, damages and
#   liabilities asserted by third parties (including claims for
#   negligence) which arise directly or indirectly from the use of the
#   Software or the sale of any products based on the Software.
#   
#   No part of the Software may be reproduced, modified, transmitted or
#   transferred in any form or by any means, electronic or mechanical,
#   without the express permission of the University. The permission of
#   the University is not required if the said reproduction, modification,
#   transmission or transference is done without financial return, the
#   conditions of this Licence are imposed upon the receiver of the
#   product, and all original and amended source code is included in any
#   transmitted product. You may be held legally responsible for any
#   copyright infringement that is caused or encouraged by your failure to
#   abide by these terms and conditions.
#   
#   You are not permitted under this Licence to use this Software
#   commercially. Use for which any financial return is received shall be
#   defined as commercial use, and includes (1) integration of all or part
#   of the source code or the Software into a product for sale or license
#   by or on behalf of Licensee to third parties or (2) use of the
#   Software or any derivative of it for research with the final aim of
#   developing software products for sale or license to a third party or
#   (3) use of the Software or any derivative of it for research with the
#   final aim of developing non-software products for sale or license to a
#   third party, or (4) use of the Software to provide any service to an
#   external organisation for which payment is received. If you are
#   interested in using the Software commercially, please contact Isis
#   Innovation Limited ("Isis"), the technology transfer company of the
#   University, to negotiate a licence. Contact details are:
#   innovation@isis.ox.ac.uk quoting reference DE/1112.

#}}}
#{{{ script setup

# the next line restarts using wish \
exec $FSLTCLSH "$0" "$@"

set INGUI 0

source $env(FSLDIR)/tcl/fslstart.tcl

#}}}
#{{{ proc runregfiles

proc runregfiles { filename } {

    if { ! [ imtest reg_standard/$filename ] } {
	return 1
    } elseif { [ file mtime [ imglob -oneperimage reg_standard/$filename ] ] < [ file mtime $filename ] || [ file mtime [ imglob -oneperimage reg_standard/$filename ] ] < [ file mtime reg/example_func2standard.mat ] } {
	return 1
    } else {
	return 0
    }
}

#}}}
#{{{ proc runflirt

proc runflirt { flirtcommand output } {
    global FSLDIR
    set TMPNAM [ fsl:exec "${FSLDIR}/bin/tmpnam frgrot" -n ]
    fsl:exec "$flirtcommand -o $TMPNAM"
    immv $TMPNAM $output
    fsl:exec "/bin/rm $TMPNAM" -n
}

#}}}
#{{{ process options

if { [ lindex $argv 0 ] == "" } {
    puts "
Usage: featregapply <feat_directory> \[-f\] \[-c\]
  -f : force featregapply to run even if already run on this FEAT directory
  -c : cleanup, i.e. remove all featregapply output
"
    exit 1
}

cd [ lindex $argv 0 ]

# if not first-level analysis, nothing to do, so exit
if { [ file exists design.lev ] } {
    exit 0
}

feat5:setupdefaults
feat5:load -1 1 design.fsf

# for older first-level FEAT dirs: create mean_func if it's not already there
if { [ imtest filtered_func_data ] && ! [ imtest mean_func ] } {
    fsl:exec "${FSLDIR}/bin/fslmaths filtered_func_data -Tmean mean_func"
}

set force 0
set cleanup 0
for { set i 1 } { $i < [ llength $argv ] } { incr i 1 } {
    if { ! [ string compare [ lindex $argv $i ] "-f" ] } {
	set force 1
    } elseif { ! [ string compare [ lindex $argv $i ] "-c" ] } {
	set cleanup 1
    }
}

if { $cleanup || $force } {
    fsl:exec "/bin/rm -rf reg_standard"
    if { $cleanup } { exit 0 }
}

if { ! [ file exists reg/example_func2standard.mat ] } {
    puts "Error - registration has not been run for [ pwd ]"
    exit 1
}

catch { exec sh -c "mkdir -p reg_standard/reg reg_standard/stats" } errmsg

#}}}


#{{{ setup background image

set BGIMAGE ""
set BGMAT ""
switch $fmri(bgimage) {
    1 -
    2 { set BGIMAGE highres ; set BGMAT "-init reg/highres2standard.mat" }
    3 -
    4 { set BGIMAGE example_func ; set BGMAT "-init reg/example_func2standard.mat" }
}

if { ! [ imtest reg/$BGIMAGE ] } {
    set BGIMAGE standard
}

#}}}
#{{{ apply the registration

set FL "${FSLDIR}/bin/flirt -ref reg/standard -applyxfm"

# MELODIC upsampling
if { [ info exists fmri(inmelodic) ] && $fmri(inmelodic) } {
    if { $fmri(regstandard_res)>0.0001 } {
	set FL "${FSLDIR}/bin/flirt -ref reg/standard -applyisoxfm $fmri(regstandard_res)"
    }
    runflirt "$FL -in reg/$BGIMAGE $BGMAT -interp sinc -datatype float" reg_standard/bg_image
    runflirt "$FL -in filtered_func_data -init reg/example_func2standard.mat -datatype float" reg_standard/filtered_func_data
    fsl:exec "${FSLDIR}/bin/fslmaths reg_standard/filtered_func_data -Tstd -bin reg_standard/mask -odt char"
} else {
    # sinc interpolated lowres images
    foreach input [ imglob -oneperimage example_func.* ] {
	if { [ runregfiles $input ] } {
	    runflirt "$FL -in $input -init reg/example_func2standard.mat -interp sinc -datatype float" reg_standard/$input
	}
    }

    # nearestneighbour interpolated lowres images
    foreach input [ imglob -oneperimage mask.* ] {
	if { [ runregfiles $input ] } {
	    runflirt "$FL -in $input -init reg/example_func2standard.mat -interp nearestneighbour" reg_standard/$input
	}
    }

    # trilinear interpolated lowres images
    foreach input [ imglob -oneperimage mean_func* stats/cope* stats/varcope* stats/tdof_t* ] {
	if { [ runregfiles $input ] } {
	    runflirt "$FL -in $input -init reg/example_func2standard.mat" reg_standard/$input
	}
    }

    # highres images
    if { [ file exists reg/highres2standard.mat ] } {
	foreach input [ imglob -oneperimage reg/highres.* ] {
	    if { [ runregfiles $input ] } {
		runflirt "$FL -in $input -init reg/highres2standard.mat -interp sinc -datatype float" reg_standard/$input
	    }
	}
    }
}

#}}}

