/*
 * Miscellaneous stuff for BWap
 *
 * Author: Brian Weiss <brian@got.net> - 2000
 */

assign AUTO_REJOIN 1

alias c (level, void)
{
	switch ($level)
	{
		(0) {admin setchanlevel $C leech}
		(1) {admin setchanlevel $C user}
		(2) {admin setchanlevel $C moderator}
		(3) {admin setchanlevel $C admin}
		(4) {admin setchanlevel $C elite}
		(*) {
			xecho -b Usage: /c <#> - leech(0)/user(1)/moderator(2)/admin(3)/elite(4)
			xecho -b    - Sets channel level to <#>
		}
	}
}

alias links (void)
{
	admin links
}

alias lusers (void)
{
	admin stats
}

alias operview (void)
{
	if (!OPERVIEW)
	{
		window new size 5 name ov level server last
		^assign OPERVIEW 1
		xecho -b OperView [ON]
	}{
		window refnum ov kill
		^assign -OPERVIEW
		xecho -b OperView [OFF]
	}
}

alias ov operview

alias pingme (void)
{
	ping $N
}

alias q query

alias quote raw

alias sv version

alias swap (winnum, void)
{
	if (winnum)
	{
		window swap $winnum
	}{
		input "What window should we swap to? "
		{
			window swap $0
		}
	}
}

alias tmuzzle (time, nick, reason)
{
	if (time && nick)
	{
		muzzle $nick ${reason ? reason : [Temporary muzzle for $time seconds]}
		timer $time unmuzzle $nick
	}{
		xecho -b Usage: /tmuzzle <seconds> <nick> [reason]
	}
}

alias wi (nicks)
{
	if (nicks)
	{
		fe ($nicks) n1
		{
			whois $n1
		}
	}{
		whois $N
	}
}

on -404 '% % $N out of channel *'
{
	if (AUTO_REJOIN)
	{
		join $sar(g/://$6)
	}
}
